sed 處理多行合并

rm-rf

文件格式

table=t1
name
owner
address
table=t2
id
text
col1
comment
col5
table=t3
prod_name
price

要求按table=關(guān)鍵字，將相同的table的列放在同一行，結(jié)果為:

table=t1 name owner address
table=t2 id text col1 comment col5
table=t3 prod_name price

另外要求只能用sed

elu_ligao

1. sed ':a /^table/{N;/\ntable/{P;D};s/\n/ /g;b a}'

復(fù)制代碼

moperyblue

1. sed '/table/{:a;N;/\ntable/!{s/\n/ /;ta};P;D}' file
   
2. sed '/table/{:a;${s/\n/ /g};N;/\ntable/!ba;h;s/\n[^\n]*$//;s/\n/ /gp;g;s/.*\n//;ba}' file

復(fù)制代碼

rm-rf

樓上3位的腳本都能得倒我想要的，感謝了。

我是一隻羊

1. sed ':1;N;/\ntable/{P;D};s/\n/ /;b1'

復(fù)制代碼

ly5066113

回復(fù) 1# rm-rf

1. sed ':a;N;/\ntable=/!s/\n/ /;ta;P;D' file

復(fù)制代碼

waker

1. sed '/^table/{x;s/\n/ /g;b};H;d' urfile

復(fù)制代碼

moperyblue

回復(fù) 7# waker


這樣最后一個table所在行及后面的內(nèi)容都沒法顯示

sed '/table/{x;s/\n/ /g;b};H;${g;s/\n/ /gp};d'

jason680

>> 求按table=關(guān)鍵字，將相同的table的列放在同一行，結(jié)果為:

$ awk '/^table=/{sub(/ $/,"\n",p)}{p=p$0" "}END{print p}' FILE
table=t1 name owner address
table=t2 id text col1 comment col5
table=t3 prod_name price

jcdiy0601

1. sed ':a;$!N;/\ntable/!s/\n/ /;ta;P;D' file

復(fù)制代碼