arm中斷異常時(shí)cpsr顯示都是svc模式？

blake326

有個(gè)疑問，
在中斷處理中，打印cpsr發(fā)現(xiàn)mode=0x13 處于svc mode。
data abort處理中，打印cpsr發(fā)現(xiàn)mode=0x13
看來kernel只用了user mode和svc mode。

1. 如果是這樣的，那么怎樣實(shí)現(xiàn)只用兩種mode的呢？
2. 如果是這樣的，那么中斷異常處理中(從usr mode到svc mode）， sp是從usr sp自動(dòng)切換到svc sp的，硬件自動(dòng)處理嗎，從文檔上沒有看到相關(guān)部分。

daniel_11

blake326 發(fā)表于 2013-07-11 09:11
有個(gè)疑問，
在中斷處理中，打印cpsr發(fā)現(xiàn)mode=0x13 處于svc mode。
data abort處理中，打印cpsr發(fā)現(xiàn)mode=0 ...

個(gè)人認(rèn)為，有內(nèi)核態(tài)，用戶態(tài)就夠用了。
對(duì)于異常和中斷，應(yīng)該有不同。通常中斷由硬件處理，異常就不一定。異常/系統(tǒng)調(diào)用只是提供從用戶態(tài)到內(nèi)核態(tài)的方法，可以軟件具體實(shí)現(xiàn)。

arm-linux-gcc

中斷異常時(shí)是切換到了svc模式下去處理的

在irq模式下，只是將lr r0 spsr入棧，irq模式的棧size只有3個(gè)word，剛好夠放這三個(gè)寄存器
然后將irq模式的�；�地址填到r0中，然后切換到svc模式
在svc模式下通過r0就可以取出lr r0 spsr，然后將lr和r0和r1-sp都?jí)喝雜vc模式的棧（此時(shí)是借用的被中斷的線程的棧），將spsr寫入svc模式的spsr
然后就進(jìn)行中斷處理
處理完之后，就可以直接從svc模式返回到發(fā)生中斷之前的模式

smalloc

回復(fù) 2# daniel_11


    嵌套中斷的要求：

blake326

回復(fù) 3# arm-linux-gcc

》》》》》》》》》》》
    然后將irq模式的�；�地址填到r0中，然后切換到svc模式
》》》》》》》》》》

你的意思是發(fā)生中斷后，會(huì)進(jìn)入irq模式，然后保存了r0,lr,spsr之后，kernel就立刻切換到了svc模式？那么這個(gè)切換的動(dòng)作在哪里的，svc_entry? 我看代碼沒有找到這個(gè)動(dòng)作。

blake326

回復(fù) 4# smalloc


    那么你的意思是在中斷處理中，arm處于irq mode嗎？
    但是我打出來的都是arm處于svc mode，不過我的板子用了vlx虛擬機(jī)，可能有影響。

arm-linux-gcc

回復(fù) 6# blake326

從irq到svc的切換過程如下：

        .macro        vector_stub, name, mode, correction=0
        .align        5

vector_\name:
        .if \correction
        sub        lr, lr, #\correction
        .endif

        @
        @ Save r0, lr_<exception> (parent PC) and spsr_<exception>
        @ (parent CPSR)
        @
        stmia        sp, {r0, lr}                @ save r0, lr
        mrs        lr, spsr
        str        lr, [sp, #8]                @ save spsr

        @
        @ Prepare for SVC32 mode.  IRQs remain disabled.
        @
        mrs        r0, cpsr
        eor        r0, r0, #(\mode ^ SVC_MODE | PSR_ISETSTATE)         
        msr        spsr_cxsf, r0
以上3句是將spsr中的模式位改為svc，注意這里只是修改了irq的spsr，還未切換狀態(tài)

        @
        @ the branch table must immediately follow this code
        @
        and        lr, lr, #0x0f                    取出spsr中的[M3:M0]，這里不用取M4，因?yàn)镸4是表示26位還是32位尋址的，如果只想知道模式的話，取[M3:M0]就夠了
THUMB(        adr        r0, 1f                        )
THUMB(        ldr        lr, [r0, lr, lsl #2]        )
        mov        r0, sp                            將irq模式的�；�地址填到r0，以后在svc_entry中可以通過r0去讀取irq的棧
ARM(        ldr        lr, [pc, lr, lsl #2]        )         直接將[M3:M0]乘以4再加上pc就可以計(jì)算出入口（因?yàn)橐粋�(gè)entry占4個(gè)字節(jié)），結(jié)果為__irq_usr或__irq_svc，具體是usr還是svc要看發(fā)生中斷之前是什么模式
        movs        pc, lr                        @ branch to handler in SVC mode        跳進(jìn)入口（__irq_usr或__irq_svc），同時(shí)做模式切換（mov帶了s，就會(huì)給pc賦值的同時(shí)將用spsr去填cpsr）
ENDPROC(vector_\name)


        vector_stub        irq, IRQ_MODE, 4                        宏vector_\name展開，展開之后的結(jié)果，使得上述 ARM(ldr lr,[pc,lr,lsl #2])處的pc值就是下面的.long        __irq_usr處的地址

        .long        __irq_usr                        @  0  (USR_26 / USR_32)           [M3:M0]為0
        .long        __irq_invalid                        @  1  (FIQ_26 / FIQ_32)
        .long        __irq_invalid                        @  2  (IRQ_26 / IRQ_32)
        .long        __irq_svc                        @  3  (SVC_26 / SVC_32)           [M3:M0]為3
        .long        __irq_invalid                        @  4
        .long        __irq_invalid                        @  5
        .long        __irq_invalid                        @  6
        .long        __irq_invalid                        @  7
        .long        __irq_invalid                        @  8
        .long        __irq_invalid                        @  9
        .long        __irq_invalid                        @  a
        .long        __irq_invalid                        @  b
        .long        __irq_invalid                        @  c
        .long        __irq_invalid                        @  d
        .long        __irq_invalid                        @  e
        .long        __irq_invalid                        @  f
其中一些是占位符，這里剛好16個(gè)，對(duì)應(yīng)了[M3:M0]的所有可能取值，所以entry的地址就可以用[M3:M0]很快的算出來，之所以弄16個(gè)entry，是因?yàn)閇M3:M0]在各種模式的取值中并不是連續(xù)的


你在svc_entry是看不到模式切換的，因?yàn)樵谶M(jìn)入svc_entry之前就已經(jīng)做了，你可以去直接看irq的棧，可以查看以下數(shù)據(jù)結(jié)構(gòu)
arch/arm/kernel/setup.c，他們分別是irq abt und模式的棧
struct stack {
        u32 irq[3];
        u32 abt[3];
        u32 und[3];
} ____cacheline_aligned;




寫的挺亂的，不知道說清楚沒，向來不善于寫這類東西

arm-linux-gcc

另貼一個(gè)CPSR的模式位以便對(duì)比看


M4 M3 M2 M1 M0
0   0   0   0   0     User26 模式
0   0   0   0   1     FIQ26 模式
0   0   0   1   0     IRQ26 模式
0   0   0   1   1     SVC26 模式
1   0   0   0   0     User 模式
1   0   0   0   1     FIQ 模式
1   0   0   1   0     IRQ 模式
1   0   0   1   1     SVC 模式
1   0   1   1   1     ABT 模式
1   1   0   1   1     UND 模式

blake326

回復(fù) 7# arm-linux-gcc

》》》》》》
          movs        pc, lr                        @ branch to handler in SVC mode   


謝謝。這段代碼我也看過幾遍，原來是在這句切到svc mode的。沒有注意到 movs指令。

super皮波

為何irq模式的棧只有3個(gè)word，irq的sp是在哪賦值的？多謝
回復(fù) 3# arm-linux-gcc